Supercharge your PowerPoint productivity with
Supercharge your PPT Productivity with PPTools - Click here to learn more.

PPTools

Image Export converts PowerPoint slides to high-quality images.

PPT2HTML exports HTML even from PowerPoint 2010 and 2013, gives you full control of PowerPoint HTML output, helps meet Section 508 accessibility requirements

Merge Excel data into PowerPoint presentations to create certificates, awards presentations, personalized presentations and more

Resize your presentations quickly and without distortion

Language Selector switches the text in your presentation from one language to another

FixLinks prevents broken links when you distribute PowerPoint presentations

Shape Styles brings styles to PowerPoint. Apply complex formatting with a single click.

Prep4PDF preserves interactivity in PowerPoint presentations when you convert to PDF

Batch re-save presentations; update older presentations to newer PowerPoint version

Problem

You have a folder full of PowerPoint files from an older version and want to open and resave each to the current PowerPoint version. For example, newer versions of PowerPoint won't open PowerPoint 95 files but you can open them in PowerPoint 97, 2000, 2002 or 2003 and save again; after that you can open them in the newer PPT versions.

Or you have files that have been edited repeatedly and saved with PowerPoint's dreaded Fast Saves enabled. They've become huge and bloated. You've turned Fast Saves off but now you need to open and resave every file to clean out the fat.

For just a few files, this is simple. But suppose you have hundreds of them? You need an automated solution.

Automation to the rescue

If you're using a version of PowerPoint that won't open your files, you'll need to find a computer with an earlier PowerPoint version that can open them and perform the conversion there.

Take note of the folder where the files are stored. You'll need to type the complete path to it.

Run this macro. It will open and resave each PPT file it finds in the folder you specify.

When done, you'll have two versions of each file you started with. The original is renamed to OriginalName.PPT.OLD and the newly saved file has the same name as the original did.

Sub BatchSave()
' Opens each PPT in the target folder and saves as PPT97-2003 format

    Dim sFolder As String
    Dim sPresentationName As String
    Dim oPresentation As Presentation

    ' Get the foldername:

    sFolder = InputBox("Folder containing PPT files to process", "Folder")

    If sFolder = "" Then
        Exit Sub
    End If

    ' Make sure the folder name has a trailing backslash
    If Right$(sFolder, 1) <> "\" Then
        sFolder = sFolder & "\"
    End If

    ' Are there PPT files there?
    If Len(Dir$(sFolder & "*.PPT")) = 0 Then
        MsgBox "Bad folder name or no PPT files in folder."
        Exit Sub
    End If

    ' Open and save the presentations
    sPresentationName = Dir$(sFolder & "*.PPT")
    While sPresentationName <> ""
        Set oPresentation = Presentations.Open(sFolder & sPresentationName, , , False)
        Call oPresentation.SaveAs(sFolder & "N_" & sPresentationName, ppSaveAsPresentation)
        oPresentation.Close
        ' New presentation is now saved as N_originalname.ppt
        ' Now let's rename them - comment out the next couple lines
        '   if you don't want to do this
        ' Original.PPT to Original.PPT.OLD
        Name sFolder & sPresentationName As sFolder & sPresentationName & ".OLD"
        ' N_Original.PPT to Original.PPT
        Name sFolder & "N_" & sPresentationName As sFolder & sPresentationName
        sPresentationName = Dir$()
    Wend

    MsgBox "DONE"

End Sub

See How do I use VBA code in PowerPoint? to learn how to use this example code.


Did this solve your problem? If so, please consider supporting the PPT FAQ with a small PayPal donation.
Page copy protected against web site content infringement by Copyscape Contents © 1995 - 2015 Stephen Rindsberg, Rindsberg Photography, Inc. and members of the MS PowerPoint MVP team. You may link to this page but any form of unauthorized reproduction of this page's contents is expressly forbidden.
Español    Deutsch    Français    Português    Italiano    Nederlands    Greek    Japanese    Korean    Chinese

Supercharge your PPT Productivity with PPTools

content authoring & site maintenance by
Friday, the automatic faq maker (logo)
Friday - The Automatic FAQ Maker

Batch re-save presentations; update older presentations to newer PowerPoint version
http://www.pptfaq.com/FAQ00740_Batch_re-save_presentations-_update_older_presentations_to_newer_PowerPoint_version.htm
Last update 07 June, 2011
Created: